Windows常用脚本总结

2023年8月18日 10:04:22

Windows常用脚本放到了Gitee和GitHub。

✨项目地址:

• https://gitee.com/javakam/windows-script
• https://github.com/javakam/Windows-Scripts

常用脚本(Batchfile & VBScript)

1. 一键发动.bat

一次双击敞开多个软件, 不必逐个软件双击翻开, 十分便利！

@echo off
mode con lines=30 cols=100
title= 一键发动
:main
cls
color 2e
echo %time%
echo.Martin's Blog  https://javakam.github.io
color 1f
echo.-----------------------------------------------------------
echo Starting QQ...
start "" "C:\Program Files (x86)\Tencent\QQ\Bin\QQScLauncher.exe"
echo Starting WeChat...
start "" "C:\Program Files\Tencent\WeChat\WeChat.exe"
:end
echo 执行完成

2. Win11改用传统右键菜单.bat

切换Win11的右键菜单 或 Win10旧版菜单。例如切换到Win10旧版右键菜单:

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
@echo off
echo. 
echo ============================================= 
echo 右键菜单类型
echo 1 (Win10旧版右键菜单)
echo 2 (Win11新版右键菜单)
echo ============================================= 
:select
set /p opt=请挑选操作：
if %opt%==1 (
    echo 正在敞开Win10旧版右键菜单》》》》》》》》》
	reg add "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve
)
if %opt%==2 (
    echo 正在康复Win11新版右键菜单》》》》》》》》》
	reg delete "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}" /f
)
@echo off
echo *************************************
echo *                                   *
echo *          重启使命办理器...        *
echo *                                   *
echo *************************************
taskkill /f /im explorer.exe & start explorer.exe
pause

两种菜单款式随时切换, 很便利。

3. Java多版别切换

①以java1.8和java17为例, 目录结构为:

②环境变量装备

Path:

③SwitchJDK.bat源码及运转作用:

@echo off
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
@echo off
rem --- Base Config 装备JDK的装置目录 ---
:init 
set JAVA_HOME8=C:\fastwork\Java\jdk1.8
set JAVA_HOME17=C:\fastwork\Java\jdk17
:start 
echo 当时使用的JDK 版别: 
java -version 
echo. 
echo ============================================= 
echo jdk版别列表 
echo 1 (1.8)
echo 2 (17)
echo ============================================= 
:select
set /p opt=请挑选jdk版别： 
if %opt%==1 (
    set TARGET_JAVA_HOME=%JAVA_HOME8%
)
if %opt%==2 (
    set TARGET_JAVA_HOME=%JAVA_HOME17%
)
echo 当时挑选的Java途径:%TARGET_JAVA_HOME%
wmic ENVIRONMENT where "name='JAVA_HOME'" delete
wmic ENVIRONMENT create name="JAVA_HOME",username="<system>",VariableValue="%TARGET_JAVA_HOME%"
rem -- refresh env ---
call RefreshEnv
echo 请按任意键退出!
pause>nul

注: 修改环境变量后, 必须使用Win+R翻开cmd的新窗口,再输入java -version进行验证才准确。此刻Android Studio中的Terminal验证显现仍是旧的java环境, 重启AS即可。

4. Windows设置/取消守时关机

守时关机3H.bat

Shutdown -s -t 10800

取消守时关机.bat

Shutdown -a

5. 操控某个服务的敞开/封闭

以某品牌移动硬盘的服务为例: 右键开始挑选计算机办理->服务和应用程序中双击服务->找到指定服务并检查属性

把服务称号放到net start/stop 后边即可:

@echo off
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
if '%errorlevel%' NEQ '0' (
goto UACPrompt
) else ( goto gotAdmin )
:UACPrompt
echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
exit /B
:gotAdmin
if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
@echo off
echo. 
echo ============================================= 
echo 操作类型
echo 1 (敞开服务)
echo 2 (封闭服务)
echo ============================================= 
:select
set /p opt=请挑选操作：
if %opt%==1 (
    echo 敞开服务
    net start "TosHddscSvc"
)
if %opt%==2 (
    echo 封闭服务
    net stop "TosHddscSvc"
)
::pause
setlocal enabledelayedexpansion
echo 执行结束，脚本5秒后主动退出...
set /a count=5
:loop
echo 剩余时间：%count% 秒
timeout /t 1 >nul
set /a count-=1
if %count% gtr 0 (
    goto loop
) else (
    echo 脚本退出
)
endlocal
exit

执行作用(此处设置了bat倒计时主动退出):

设置开机发动脚本

就两步:
①新建xxx.vbs, 设置需要开机发动的bat文件名:

set ws=wscript.createobject("wscript.shell")
ws.run "xxxxxx.bat /start",0

②把vbs脚本源文件或快捷方式放到

C:\Users\用户名\AppData\Roaming\Microsoft\Windows\Start Menu\Programs\Startup

目录下, 开机后会主动执行。如下图所示:

附1 jupyter开机发动vbs

jupyter_startup.vbs

Dim wsh
Set wsh = createobject("wscript.Shell")
'1. 使用装备文件发动 jupyter_notebook_config.py
'wsh.run "cmd /c jupyter notebook --no-browser", 0, true
'2. 直接进入途径发动[推荐]
wsh.run "cmd /c jupyter notebook --notebook-dir='C:\fastwork\Python\JupyterNotebook' --no-browser", 0, true
Set wsh = Nothing

其中JupyterNotebook为存放*.ipynb文件的目录:

附2 redis开机发动vbs

service_redis_startup.vbs

set ws=wscript.createobject("wscript.shell")
ws.run "service_start.bat /start",0

service_start.bat

::发动redis的命令
@echo off
::这是简单的输出，相当于java中的system.out.println()
echo redis-server start......
::设置发动窗口的标题
title redis-server
::定义一个变量ENV_HOME
set ENV_HOME="C:\fastwork\Redis"
C:
::设置发动窗口的色彩
color 0a
cd %ENV_HOME%
redis-server.exe redis.windows.conf
exit

常用jar包

源码地址: gitee.com/javakam/Fil…

使用方法: java -jar xxx.jar

FileCleaner.jar 用于整理Android/Java项目的暂时编译目录,如build classes target 等

FileSizeCalculator.jar 用于检查目录中所有文件的巨细,现在仅支撑MB为单位,便于删除大文件

常用Python脚本

todo 2023年8月9日 15:16:41

✨下载地址

https://gitee.com/javakam/windows-script

https://github.com/javakam/Windows-Scripts

注: 如有360、电脑管家等安全软件提示，请勾选信赖允许和不再提示！