概念
存储进程(Stored Procedure):已预编译为一个可履行进程的一个或多个SQL句子。
创立存储进程语法
CREATE proc | procedure procedure_name
[{@参数数据类型} [=默认值] [output],
{@参数数据类型} [=默认值] [output],
....
]
as
SQL_statementsgo
存储进程与SQL句子比照
优势:
1、提高性能
SQL句子在创立进程时进行剖析和编译。 存储进程是预编译的,在初次运转一个存储进程时,查询优化器对其进行剖析、优化,并给出最终被存在系统表中的存储计划,这样,在履行进程时便可节省此开支。
2、降低网络开支
存储进程调用时只需用供给存储进程名和必要的参数信息,然后可降低网络的流量。
3、便于进行代码移植
数据库专业人员能够随时对存储进程进行修改,但对运用程序源代码却毫无影响,然后极大的提高了程序的可移植性。
4、更强的安全性
1)系统管理员能够对履行的某一个存储进程进行权限约束,防止非授权用户对数据的拜访
2)在通过网络调用进程时,只要对履行进程的调用是可见的。 因此,恶意用户无法看到表和数据库目标称号、嵌入自己的 Transact-SQL 句子或查找要害数据。
3)运用进程参数有助于防止 SQL 注入进犯。 因为参数输入被视作文字值而非可履行代码,所以,进犯者将命令插入进程内的 Transact-SQL 句子并危害安全性将更为困难。
4)能够对进程进行加密,这有助于对源代码进行含糊处理。
劣势:
1、存储进程需求专门的数据库开发人员进行保护,但实际情况是,往往由程序开发员人员兼职
2、规划逻辑变更,修改存储进程没有SQL灵活
为什么在实际运用中,存储进程用到相对较少呢?
在通常的项目研制中,用存储进程却相对较少,这是为什么呢?
剖析原因如下:
1)没有特定的数据库开发人员,一般程序员兼职进行数据库操作
2)程序员往往只需操作程序,即可完结数据拜访,无需再在数据库上进行开发
3)项目需求变动比较频繁,修改SQL句子比较便利,特别是触及逻辑变更
存储进程与SQL句子如何抉择?
依据实际运用的经验,给予如下主张:
1、在一些高效率或许规范性要求比较高的项目,主张选用存储进程
2、对于一般项目主张选用参数化命令方法,是存储进程与SQL句子一种折中的方法
3、对于一些算法要求比较高,触及多条数据逻辑,主张选用存储进程
存储进程的详细运用
一、根底查询
1、创立不带参数的存储进程
例子:查询学生总数
--查询存储进程
IF OBJECT_ID (N'PROC_SELECT_STUDENTS_COUNT', N'P') IS NOT NULL
DROP procedure PROC_SELECT_STUDENTS_COUNT;
GO
CREATE procedure PROC_SELECT_STUDENTS_COUNT
AS
SELECT COUNT(ID) FROM Students
GO
履行:
EXEC PROC_SELECT_STUDENTS_COUNT
2、带参数的存储进程
--查询存储进程,依据城市查询总数
IF OBJECT_ID (N'PROC_SELECT_STUDENTS_BY_CITY_COUNT', N'P') IS NOT NULL
DROP procedure PROC_SELECT_STUDENTS_BY_CITY_COUNT;
GO
CREATE procedure PROC_SELECT_STUDENTS_BY_CITY_COUNT(@city nvarchar(50))
AS
SELECT COUNT(ID) FROM Students WHERE City=@city
GO
履行句子:
EXEC PROC_SELECT_STUDENTS_BY_CITY_COUNT N'Beijing'
3、带有通配符
通配符,在参数值赋值时,加上相应的通配符
--3、查询姓氏为李的学生信息,含通配符
IF OBJECT_ID (N'PROC_SELECT_STUDENTS_BY_SURNNAME', N'P') IS NOT NULL
DROP procedure PROC_SELECT_STUDENTS_BY_SURNNAME;
GO
CREATE procedure PROC_SELECT_STUDENTS_BY_SURNNAME
@surnName nvarchar(20)='李%' --默认值
AS
SELECT ID,Name,Age FROM Students WHERE Name like @surnName
GO
履行:
EXEC PROC_SELECT_STUDENTS_BY_SURNNAME
EXEC PROC_SELECT_STUDENTS_BY_SURNNAME N'李%'
EXEC PROC_SELECT_STUDENTS_BY_SURNNAME N'%李%'
4、带有输出参数
--依据名字查询的学生信息,返回学生的城市及年龄
IF OBJECT_ID (N'PROC_SELECT_STUDENTS_BY_NAME', N'P') IS NOT NULL
DROP procedure PROC_SELECT_STUDENTS_BY_NAME;
GO
CREATE procedure PROC_SELECT_STUDENTS_BY_NAME
@name nvarchar(50), --输入参数
@city nvarchar(20) out, --输出参数
@age int output --输入输出参数
AS
SELECT @city=City,@age=Age FROM Students WHERE Name=@name AND Age=@age
GO
履行:
--履行
declare @name nvarchar(50),
@city nvarchar(20),
@age int;
set @name = N'李明';
set @age = 20;
exec PROC_SELECT_STUDENTS_BY_NAME @name,@city out, @age output;
select @city, @age;
二、运用存储进程进行增删改
1、新增
新增学生信息
--1、存储进程:新增学生信息
IF OBJECT_ID (N'PROC_INSERT_STUDENT', N'P') IS NOT NULL
DROP procedure PROC_INSERT_STUDENT;
GO
CREATE procedure PROC_INSERT_STUDENT
@id int,
@name nvarchar(20),
@age int,
@city nvarchar(20)
AS
INSERT INTO Students(ID,Name,Age,City) VALUES(@id,@name,@age,@city)
GO
履行:
EXEC PROC_INSERT_STUDENT 1001,N'张三',19,'ShangHai'
2、修改
依据学生ID,更新学生信息
IF OBJECT_ID (N'PROC_UPDATE_STUDENT', N'P') IS NOT NULL
DROP procedure PROC_UPDATE_STUDENT;
GO
CREATE procedure PROC_UPDATE_STUDENT
@id int,
@name nvarchar(20),
@age int,
@city nvarchar(20)
AS
UPDATE Students SET Name=@name,Age=@age,City=@city WHERE ID=@id
GO
履行:
EXEC PROC_UPDATE_STUDENT 1001,N'张思',20,'ShangHai'
3、删去
依据ID,删去某学生记载
--3、存储进程:删去学生信息
IF OBJECT_ID (N'PROC_DELETE_STUDENT_BY_ID', N'P') IS NOT NULL
DROP procedure PROC_DELETE_STUDENT_BY_ID;
GO
CREATE procedure PROC_DELETE_STUDENT_BY_ID
@id int
AS
DELETE FROM Students WHERE ID=@id
GO
履行:
EXEC PROC_DELETE_STUDENT_BY_ID 1001
三、存储进程完成分页查询
1、运用row_number函数分页
--分页查询
IF OBJECT_ID (N'PROC_SELECT_BY_PAGE', N'P') IS NOT NULL
DROP procedure PROC_SELECT_BY_PAGE;
GO
CREATE procedure PROC_SELECT_BY_PAGE
@startIndex int,
@endIndex int
AS
SELECT * FROM (SELECT ID,Name,Age,City,ROW_NUMBER() OVER(ORDER BY ID DESC) AS RowNumber FROM Students) AS Temp
WHERE Temp.RowNumber BETWEEN @startIndex AND @endIndex
GO
履行:
EXEC PROC_SELECT_BY_PAGE 1,10
2、运用传统的top分页
--运用TOP分页
IF OBJECT_ID (N'PROC_SELECT_BY_PAGE_WITH_TOP', N'P') IS NOT NULL
DROP procedure PROC_SELECT_BY_PAGE_WITH_TOP;
GO
CREATE procedure PROC_SELECT_BY_PAGE_WITH_TOP
@pageIndex int,
@pageSize int
AS
SELECT TOP(@pageSize) * FROM Students
WHERE ID >=(SELECT MAX(ID) FROM (SELECT TOP(@pageSize*(@pageIndex-1) + 1) ID FROM Students ORDER BY ID) AS Temp)
GO
履行:
EXEC PROC_SELECT_BY_PAGE_WITH_TOP 1,2
四、其他功用:
1、存储进程,每次履行都进行从头编译
--1、存储进程,重复编译
IF OBJECT_ID (N'PROC_SELECT_STUDENTS_WITH_RECOMPILE', N'P') IS NOT NULL
DROP procedure PROC_SELECT_STUDENTS_WITH_RECOMPILE;
GO
CREATE procedure PROC_SELECT_STUDENTS_WITH_RECOMPILE
with recompile --重复编译
AS
SELECT * FROM Students
GO
2、对存储进程进行加密
加密后,不能查看和修改源脚本
--2、查询存储进程,进行加密
IF OBJECT_ID (N'PROC_SELECT_STUDENTS_WITH_ENCRYPTION', N'P') IS NOT NULL
DROP procedure PROC_SELECT_STUDENTS_WITH_ENCRYPTION;
GO
CREATE procedure PROC_SELECT_STUDENTS_WITH_ENCRYPTION
with encryption --加密
AS
SELECT * FROM Students
GO
履行:
EXEC PROC_SELECT_STUDENTS_WITH_ENCRYPTION
作用,无法查看脚本或许导出创立脚本